![Imagem](https://pt-br.libreoffice.org/assets/Uploads/PT-BR-Documents/Logomarcas/LibreOfficeexternallogo600px.png)
Segue batch para deploy automatizado do LibreOffice. Para ter sempre a versão mais atual visite:
https://pt-br.libreoffice.org/baixe-ja/ ... fice-novo/
Efetue download dos instaladores "Programa principal" e "Ajuda interna do LibreOffice em português (Brasil)"
Crie um compartilhamento de rede onde todos os usuários tenham acesso somente leitura e os Domain Admins com escrita.
Agende o seguinte script para executar na GPO de inicialização dos computadores:
Código: Selecionar todos
@ECHO OFF
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:: Script para deploy do LibreOffice
:: Por Marcelo Leães - [email protected]
:: Retirado do Fórum Itbr.org - Mantenha os créditos ;)
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
SETLOCAL
:: Localiza o nome do usuário e nome da empresa que foram informados na instalação do Windows
FOR /F "tokens=*" %%A IN ('WMIC.EXE OS Get Organization^,RegisteredUser /Format:List') DO (
SET %%A>NUL
)
PUSHD "%~dp0"
:: Modo silencioso, sem reboot, log de saída
SET MSIArgs=/qn /norestart REBOOT=ReallySuppress /L \\servidor\share\LibreOffice\%computername%.log
:: Instalação completa da suite LibreOffice
SET MSIComp=ADDLOCAL=ALL
:: Associa o Writer com .DOC e o Calc com .XLS ( 0 para não )
SET MSIComp=%MSIComp% SELECT_WORD=1 SELECT_EXCEL=1
:: Associa o Impress com .PPT ( 0 para não )
SET MSIComp=%MSIComp% SELECT_POWERPOINT=1
:: Utiliza os campos coletados na instalação do LibreOffice
IF NOT "%RegisteredUser%"=="" SET MSIUser=USERNAME="%RegisteredUser%"
IF NOT "%Organization%"=="" SET MSIUser=%MSIUser% COMPANYNAME="%Organization%"
:: Executa o Instalador do LibreOffice
START /WAIT /I \\servidor\share\LibreOffice\LibreOffice_4.4.3_Win_x86.msi %MSIArgs% %MSIComp% %MSIUser%
:: Executa o Instalador do Help em Português
START /WAIT MSIEXEC.EXE /I \\servidor\share\LibreOffice\Helppack_pt-BR.msi /qn /norestart REBOOT=ReallySuppress
POPD
ENDLOCAL
:: Fim
Bom proveito !
![Wink ;)](./images/smilies/wink.gif)